; Global variables
globals
[
  ticks               ; same as time-steps
  signal-timer        ; keeps track of the time between signal changes
  signal-S            ; current state of signal for each direction 
  signal-W            
  signal-E
  stopped
  gridlocked-counter  ; stores how long a system has been gridlocked. simulation halted when this reaches a limit
  count-S
  count-W
  count-E
  live-S              ; how many cars for each direction exist on the map
  live-W
  live-E
  intersection-center
  intersection-area
  time
  stop-counter
  speed-S
  speed-W
  speed-E
  moving-S
  moving-W
  moving-E
  plot-speed-S
  plot-speed-W
  plot-speed-E
]

breeds [ car-WS car-WE car-SW car-SE car-EW car-ES ]

turtles-own
[
  alive-time
  intersection
  wait-time
  intersection-entry
  intersection-exit
  dist-patch-ahead
  stop-order ; order in which it reached the traffic light
]

patches-own
[
  road-type
]

;------------------

to setup
  ca
  setup-road  ; create the roads and traffic lights
  set signal-timer 0

  set count-S  0 set count-W  0 set count-E  0
  set speed-S  0 set speed-W  0 set speed-E  0
  set moving-S 0 set moving-W 0 set moving-E 0
  set live-S   0 set live-W   0 set live-E   0
  set plot-speed-S 0 set plot-speed-W 0 set plot-speed-E 0

  set ticks 0
  set stop-counter 0
  set stopped false
  set gridlocked-counter 0
end

;------------------

to setup-road
  let road-color 8

  ask patches [set pcolor white]      ; color background 

  ask patches
  [
    ; --------- East-West road
    if (pycor <= 0 + 3 and pycor >= 0)
    [ set pcolor road-color set road-type "road" ]
    ; --------- North-South road
    if (pycor <= 0 + 3 and pxcor >= -2 and pxcor <= 1 )
    [ set pcolor road-color set road-type "road" ]
  ]    

  ; Mark intersection-area
  set intersection-area patches with
  [ (pxcor = -3 and pycor =  2) or
    (pxcor = -2 and pycor =  1) or
    (pxcor = -1 and pycor =  1) or
    (pxcor = -1 and pycor =  0) or
    (pxcor = -1 and pycor = -1) or
    (pxcor =  0 and pycor =  1) or
    (pxcor =  1 and pycor =  1) or
    (pxcor =  2 and pycor =  2) ]

;  ; Mark intersection-area
;  set intersection-area patches with
;  [ ((pxcor >= -3 and pxcor <= 2) and (pycor >= -1 and pycor <= 2)) ]

  ; Mark intersection-center
  set intersection-center patches with
  [ ((pxcor >= -2 and pxcor <= 1) and (pycor >=  0 and pycor <= 2)) ]

  ; Mark intersection-entry
  ask (patch -2 (0 - 1)) [ set road-type "intersection-entry" ]
  ask (patch -1 (0 - 1)) [ set road-type "intersection-entry" ]
  ask (patch  2 (0 + 0)) [ set road-type "intersection-entry" ]
  ask (patch  2 (0 + 1)) [ set road-type "intersection-entry" ]
  ask (patch -3 (0 + 3)) [ set road-type "intersection-entry" ]
  ask (patch -3 (0 + 2)) [ set road-type "intersection-entry" ]
  
  ; Make agentsets for intersection-entries and lights on diff roads
  
  set signal-S patches with [ road-type = "intersection-entry" and pycor = (0 - 1) ]
  set signal-W patches with [ road-type = "intersection-entry" and pxcor = -3                             ]
  set signal-E patches with [ road-type = "intersection-entry" and pxcor =  2                             ]

  ask signal-S [ set pcolor green ]
  ask signal-W [ set pcolor red   ]
  ask signal-E [ set pcolor red   ]

  ; Mark intersection-exit
  ask (patch  0 (0 - 1)) [ set road-type "intersection-exit" ]
  ask (patch  1 (0 - 1)) [ set road-type "intersection-exit" ]
  ask (patch  2 (0 + 2)) [ set road-type "intersection-exit" ]
  ask (patch  2 (0 + 3)) [ set road-type "intersection-exit" ]
  ask (patch -3 (0 + 1)) [ set road-type "intersection-exit" ]
  ask (patch -3 (0 + 0)) [ set road-type "intersection-exit" ]
  
  ; Mark end of the road
  ask patches
  [
    if abs(pxcor) >= (screen-edge-x - 1) or abs(pycor) >= (screen-edge-y - 1) [ set road-type "end" set pcolor white] 
  ]

end

;------------------

to setup-cars
  ask patch (screen-edge-x * -1 + 1) (0 + 2) [setup-car-WS]
  ask patch -1                       (screen-edge-y * -1 + 1)       [setup-car-SE]
  ask patch (screen-edge-x - 1)      (0 + 1) [setup-car-EW]
end

;------------------

to setup-car-SE
  if (random-float 1 < car-density)
  [ sprout-car-SE 1 [ set color blue - 1  set size .8 set alive-time 0 set wait-time 0 set intersection false set heading  0  set intersection-entry patch -1 -1 set intersection-exit patch  2  2 set live-S live-S + 1] ]
end
to setup-car-WS
  if (random-float 1 < car-density)
  [ sprout-car-WS 1 [ set color red - 1   set size .8 set alive-time 0 set wait-time 0 set intersection false set heading  90 set intersection-entry patch -3  2 set intersection-exit patch  0 -1 set live-W live-W + 1] ]
end
to setup-car-EW
  if (random-float 1 <= car-density)
  [ sprout-car-EW 1 [ set color green - 1 set size .8 set alive-time 0 set wait-time 0 set intersection false set heading 270 set intersection-entry patch  2  1 set intersection-exit patch -3  1 set live-E live-E + 1] ]
end

;------------------

to go
  set stopped true
  set ticks ticks + 1

  set speed-S 0 set speed-W 0 set speed-E 0
  set moving-S 0 set moving-W 0 set moving-E 0
  
  setup-cars
  change-signal
  
  foreach shuffle values-from turtles [self]
  [ ask ?
    [
      if (road-type = "end" and alive-time > 0)
      [ decrement-live-counter die stop]
      if (patch-here = intersection-entry and intersection = false)
      [ set intersection true  intesection-set-heading set stop-order stop-counter set stop-counter stop-counter + 1 ]
      if (patch-here = intersection-exit  and intersection = true)
      [ set intersection false intesection-set-heading ]
      check-signals
      set alive-time alive-time + 1 ; used in conjunction with end to decide cars to 'kill'
    ]
  ]
  
  ifelse moving-S = 0 [ set speed-S 0 ] [ set speed-S moving-S / live-S ]
  ifelse moving-W = 0 [ set speed-W 0 ] [ set speed-W moving-W / live-W ]
  ifelse moving-E = 0 [ set speed-E 0 ] [ set speed-E moving-E / live-E ]
  set plot-speed-S plot-speed-S + speed-S
  set plot-speed-W plot-speed-W + speed-W
  set plot-speed-E plot-speed-E + speed-E

  plot-throughputs
  set-plot-x-range 0 (plot-window * 50)
  set-current-plot-pen "count-S"   set-plot-pen-interval plot-window
  set-current-plot-pen "count-W"   set-plot-pen-interval plot-window
  set-current-plot-pen "count-E"   set-plot-pen-interval plot-window
  set-current-plot-pen "count-all" set-plot-pen-interval plot-window
  if (ticks mod (plot-window * 50) = 0) [ clear-plot ]

  plot-speeds
  set-plot-x-range 0 (plot-window * 50)
  set-current-plot-pen "speed-S"   set-plot-pen-interval plot-window
  set-current-plot-pen "speed-W"   set-plot-pen-interval plot-window
  set-current-plot-pen "speed-E"   set-plot-pen-interval plot-window
  set-current-plot-pen "speed-all" set-plot-pen-interval plot-window
  if (ticks mod (plot-window * 50) = 0) [ clear-plot ]

  ifelse stopped
  [ set gridlocked-counter gridlocked-counter + 1 ]
  [ set gridlocked-counter 0 ]
end

;------------------

to change-signal

if (signal-type = "All red" or signal-type = "Stop rule")
[
  ask signal-S [ set pcolor red ] 
  ask signal-W [ set pcolor red ] 
  ask signal-E [ set pcolor red ] 
]
if signal-type = "All green"
[
  ask signal-S [ set pcolor green ] 
  ask signal-W [ set pcolor green ] 
  ask signal-E [ set pcolor green ] 
]
if signal-type = "S-red, rest green"
[
  ask signal-S [ set pcolor red ] 
  ask signal-W [ set pcolor green ] 
  ask signal-E [ set pcolor green ] 
]
if signal-type = "S-green, rest red"
[
  ask signal-S [ set pcolor green ] 
  ask signal-W [ set pcolor red ] 
  ask signal-E [ set pcolor red ] 
]
if signal-type = "E-green, rest red"
[
  ask signal-S [ set pcolor red ] 
  ask signal-W [ set pcolor red ] 
  ask signal-E [ set pcolor green ] 
]

if signal-type = "Normal"
[
  if (signal-timer < signal-cycle-time) and (signal-timer > signal-cycle-time - 3)
  [ ask signal-S [ set pcolor red   ] ask signal-E [ set pcolor red   ] ask signal-W [ set pcolor red   ] ]
  if signal-timer = signal-cycle-time
  [ ask signal-S [ set pcolor green ] ask signal-E [ set pcolor red   ] ask signal-W [ set pcolor red   ]
    set signal-timer 0
  ]

  if (signal-timer < round (signal-cycle-time * 1 / 3) and signal-timer > round (signal-cycle-time * 1 / 3) - 3) 
  [ ask signal-S [ set pcolor red   ] ask signal-E [ set pcolor red   ] ask signal-W [ set pcolor red   ] ]
  if signal-timer = round (signal-cycle-time * 1 / 3)
  [ ask signal-S [ set pcolor red   ] ask signal-E [ set pcolor green ] ask signal-W [ set pcolor red   ] ]

  if (signal-timer < round (signal-cycle-time * 2 / 3) and signal-timer > round (signal-cycle-time * 2 / 3) - 3) 
  [ ask signal-S [ set pcolor red   ] ask signal-E [ set pcolor red   ] ask signal-W [ set pcolor red   ] ]
  if signal-timer = round (signal-cycle-time * 2 / 3)
  [ ask signal-S [ set pcolor red   ] ask signal-E [ set pcolor red   ] ask signal-W [ set pcolor green ] ]

  set signal-timer signal-timer + 1
]
end

;------------------

to intesection-set-heading
  set xcor pxcor 
  set ycor pycor 
  if (breed = car-WS) [ right 45 ]
  if (breed = car-SE) [ right 45 ]
  if (breed = car-EW) [ ]
end

;------------------

to decrement-live-counter
  if (breed = car-SE)
  [ set live-S live-S - 1 ]
  if (breed = car-WS)
  [ set live-W live-W - 1 ]
  if (breed = car-EW)
  [ set live-E live-E - 1 ]
end

;------------------
  
to check-signals

  ifelse pcolor = red
  [
    ifelse (signal-type = "Stop rule")
    [
      if (stop-order = min values-from turtles-on patches with [road-type = "intersection-entry"] [ stop-order ] and 
          count turtles-on intersection-center = 0)
      [ move-ahead ]
    ]
    [
      ifelse wait-time >= wait-time-limit
      [ move-ahead ]
      [ set wait-time wait-time + 1 ]
    ]
  ]
  [ move-ahead ] ; i.e. if pcolor != red just keep moving

end

;------------------

to move-ahead

  set dist-patch-ahead 1
  if intersection = true
  [
    if (breed = car-WS or breed = car-SE )
    [ set dist-patch-ahead ( sqrt 2 ) ]
  ]
  
  ifelse (length (remove who (values-from turtles-on patch-ahead dist-patch-ahead [ who ])) > 0) or
    ((breed = car-WS or breed = car-SE ) and any? turtles-on patch-right-and-ahead 30 1 and any? turtles-on patch-left-and-ahead 30 1) or
    (pcolor = green and count turtles-on intersection-area > 5) or
    (pcolor = red and count turtles-on intersection-area > 5)
  [ set wait-time wait-time + 1 ]
  [ update-car-counts fd dist-patch-ahead set stopped false ]
end

;------------------

to update-car-counts
  if (patch-here = intersection-exit)
  [
    if (breed = car-SE)
    [ set count-S count-S + 1 ]
    if (breed = car-WS)
    [ set count-W count-W + 1 ]
    if (breed = car-EW)
    [ set count-E count-E + 1 ]
  ]
  if (breed = car-SE)
  [ set moving-S moving-S + 1 ]
  if (breed = car-WS)
  [ set moving-W moving-W + 1 ]
  if (breed = car-EW)
  [ set moving-E moving-E + 1 ]

end

;------------------

to plot-throughputs
  set-current-plot "Vehicle throughput"
  if (ticks mod plot-window = 0)
  [ 
    set-current-plot-pen "count-all" plot (count-S + count-W + count-E) / plot-window
    set-current-plot-pen "count-S"   plot count-S / plot-window set count-S 0
    set-current-plot-pen "count-W"   plot count-W / plot-window set count-W 0
    set-current-plot-pen "count-E"   plot count-E / plot-window set count-E 0
  ]
end

;------------------

to plot-speeds
  set-current-plot "Average speed"
  if (ticks mod plot-window = 0)
  [ 
    set-current-plot-pen "speed-all" plot ( plot-speed-S + plot-speed-W + plot-speed-E ) / plot-window
    set-current-plot-pen "speed-S"   plot   plot-speed-S / plot-window set plot-speed-S 0
    set-current-plot-pen "speed-W"   plot   plot-speed-W / plot-window set plot-speed-W 0
    set-current-plot-pen "speed-E"   plot   plot-speed-E / plot-window set plot-speed-E 0
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
178
10
653
506
15
15
15.0
1
10
1
1
1
0
0
0
1

CC-WINDOW
5
520
1212
615
Command Center
0

BUTTON
67
289
176
322
run forever
if gridlocked-counter < 100 [go]
T
1
T
OBSERVER
T
NIL

SLIDER
4
10
176
43
car-density
car-density
0
1
1.0
0.1
1
NIL

BUTTON
67
253
176
286
run 1 step
go
NIL
1
T
OBSERVER
NIL
NIL

PLOT
654
61
1203
247
Vehicle throughput
Time-steps
Cars / Time-step
0.0
1000.0
0.0
1.5
false
false
PENS
"count-S" 1.0 0 -13345367 true
"count-W" 1.0 0 -2674135 true
"count-E" 1.0 0 -10899396 true
"count-all" 1.0 0 -7500403 true

BUTTON
67
217
176
250
NIL
setup
NIL
1
T
OBSERVER
T
NIL

CHOOSER
32
169
176
214
signal-type
signal-type
"All red" "All green" "S-red, rest green" "S-green, rest red" "E-green, rest red" "Normal" "Stop rule"
5

SLIDER
4
49
176
82
signal-cycle-time
signal-cycle-time
30
450
60
30
1
NIL

SLIDER
4
86
176
119
wait-time-limit
wait-time-limit
0
300
60
5
1
NIL

SLIDER
4
127
176
160
plot-window
plot-window
10
200
20
10
1
NIL

MONITOR
654
10
728
59
Time-steps
ticks
0
1

PLOT
654
249
1203
435
Average speed
Time steps
Average speed
0.0
1000.0
0.0
3.0
true
false
PENS
"speed-all" 1.0 0 -7500403 true
"speed-S" 1.0 0 -13345367 true
"speed-W" 1.0 0 -2674135 true
"speed-E" 1.0 0 -10899396 true

MONITOR
729
10
789
59
NIL
speed-S
3
1

MONITOR
792
10
856
59
NIL
speed-W
3
1

MONITOR
860
10
919
59
NIL
speed-E
3
1

TEXTBOX
15
344
165
479
Note: In the paper "Self-Organizing Traffic at a Malfunctioning Intersection" (Kumar and Mitra, 2006), the directions are rotated 180 degrees, i.e. North should be replaced by South and East and West should be interchanged.

@#$#@#$#@
WHAT IS IT?
-----------
This model shows how a little bit of lawlessness can actually allow traffic at a malfunctioning intersection to flow smoothly.

The model was inspired by a real-life incident at a 3-way T-shaped intersection in New Delhi, India, where the lights were malfunctioning. The signals for two directions were frozen in the Red state, while the signal for the third direction was frozen in the Green state.

HOW IT WORKS
------------
There are cars coming from three directions, Blue cars from the South, Red cars from the West, and Green cars from the East. (Note: The original intersection was a 180 degree rotated version of this simulation - i.e. South was North, and East and West were interchanged)

Each direction of traffic has two lanes, but only one lane is simulated in this model for reasons of speed and simplicity. This is a reasonable simplification because the other lanes do not interfere with other traffic flows.

Each square patch has a side of about 2.5m and can be empty or occupied by exactly 1 car. The model explicitly forbids collisions or overtaking. All cars try to move to the patch ahead on each time-step, and remain where they are if the patch ahead is occupied or if the traffic signal prevents them from moving. Thus the velocity of the car is either 1 or 0 patches/time-step.

New cars are created at the edge of the view with a frequency depending on the value of the car-density slider.

While a car is stopped (whether at a traffic light or because of a car in front), its wait-time counter increases by 1 every time-step.

At a traffic light:
- If a car comes to a green light, it keeps moving into the intersection.
- If a car comes to a red light, it stops. The wait-time counter of a stopped car at a red light will keep increasing with every time-step, and if the wait-time eventually exceed its wait-time limit, then the car moves into the intersection. This impatience and lawlessness is the key to this model and allows several phenomena to emerge, including the smooth flow of traffic through the intersection.

However, in both cases above, a car at a traffic light about to enter the intersection will not do so if there are more than 6 cars already in the intersection area. (The interesection area includes the middle space, as well as the patches with the traffic light). Without this restriction, all traffic gets gridlocked immediately.


HOW TO USE IT
-------------
To use this model, first set the parameters using the sliders on the left, and then click the Setup button. The following values are selected by default:

- car-density: 1.0

- signal-cycle-time: 60 (Only needed in the case of functioning traffic lights)

- wait-time-limit: 80 (the time after which a waiting car loses patience and crosses the intersection)

- plot-window: 20 (number of time steps after which the Car throughput plot is updated)

- signal-combo: "Normal" (Change this to "All green" to see how traffic can gridlock if allowed to have its own way, and then change it to "S-green, rest red" to see how impatience and lawlessness allows traffic to flow smoothly, only rarely resulting in gridlock) 

Click "Run Forever" and watch the simulation.
You might need to click "Run one step" a few times if the simulation stops with no cars being created when traffic density is very low, because the Run Forever button is programmed to stop when no cars are moving in the system.
If the traffic gridlocks, click Setup to restart the simulation.


THINGS TO NOTICE
----------------
The plot on the right shows the throughput of cars per time-step, as measured by the number of cars leaving the intersection over several time-steps (the denominator is controlled by the plot-window slider)

As there are three directions, the theoretical maximum throughput is three cars per time-step but this limit is never reached because it would imply that all cars move through the intersection at the same time, which is impossible as collisions are not allowed and no patch can have more than one car at a time.

The red, green, and blue plots represent cars from the West, East and South respectively, while the gray plot represents their sum, or the total flow rate through the intersection.

Set signal-combo to "Normal"
Observe how the three directions have effectively identical rates.
Set the plot-window to about 20 to see how the three take turns peaking - which is to be expected since at any one time only one direction is allowed to move through the intersection.

Set signal-combo to "All green"
Observe how the three directions have effectively identical rates (until the system gridlocks)

Set signal-combo to "S-green, rest red"
Observe how blue (S) has a higher throughput. More interestingly, set the plot-window to a smaller number like 10 or 20 and observe how the red (W) and green (E) plots seem to oscillate, with each direction peaking in turn, similar to the way the three directions peak in turn in the "Normal" scenario.

Change wait time to a lower value and observe how gridlock happens more often, until at wait-time = 0 when the system becomes equivalent to the "All green" signal-combo.

Set signal-combo to "All red"
Again, gridlock hardly ever happens. Observe how the three directions have the same throughput curves initially (because they start  

Set signal-combo to "Stop rule" to simulate the international stop rule, where each car stops at the stop sign and waits for cars to leave the intersection, and moves into the intersection in the order in which cars arrived at the intersection.
Observe how the three plots have nearly equal throughputs.


THINGS TO TRY
-------------
See if gridlock happens in the "All green" signal-combo even if the car-density is reduced

See how increasing the plot window to its maximum setting affects the plots.

See how many ticks it takes for the traffic to gridlock in the "All green" signal-combo


RELATED MODELS
--------------
http://ccl.northwestern.edu/netlogo/models/Gridlock
http://ccl.northwestern.edu/netlogo/models/TrafficIntersection


CREDITS AND REFERENCES
----------------------
Model by: Sujai Kumar
Centre for Research in Cognitive Systems
NIIT Ltd., Synergy Building, IIT Campus, New Delhi 110016
http://ylog.org/sujai
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="experiment" repetitions="100" runMetricsEveryTick="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit ticks="5000"/>
    <exitCondition>gridlocked-counter = 100</exitCondition>
    <metric>speed-S</metric>
    <metric>speed-W</metric>
    <metric>speed-E</metric>
    <enumeratedValueSet variable="signal-type">
      <value value="&quot;Normal&quot;"/>
      <value value="&quot;S-green, rest red&quot;"/>
      <value value="&quot;Stop rule&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="wait-time-limit">
      <value value="30"/>
      <value value="40"/>
      <value value="50"/>
      <value value="60"/>
      <value value="70"/>
      <value value="80"/>
      <value value="90"/>
      <value value="100"/>
      <value value="110"/>
      <value value="120"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@